Is searchAttr == "xxxx" of Identifier:"xxxx" (from the store)?

Could you post a few lines (items) from your json data for case #3?

The JSON data I am testing with is below:

({

"Records":

      [

            {"fOffice":"Dayton"},

            {"fOffice":"Fairview Heights"}

      ],

      "RecordCount":"2"

})

The JSON response is generated by the following ASP code: ...

<code>

 Set objRecSet = CreateObject("ADODB.Recordset")
 objRecSet.CursorType = adOpenForwardOnly
 objRecSet.LockType = adLockReadOnly

 sSQL = "SELECT DISTINCT [" & strFieldName & "] FROM [" & strTableName & "] ORDER BY [" & strFieldName & "]"
 objRecSet.Open sSQL, objConnection

 Dim jsonStrObj
 jsonStrObj = RStoJSON(objRecSet)
 Response.Write jsonStrObj

</code>

The RStoJSON function is called from the following code I found on the web:

<code>

'Function to convert an ADO recordset into a JSON object
'
'Written by Tracy Dryden, Commonwealth Technology Group, Inc.
'
'Released to the public domain.

function RStoJSON(rs)
    dim sFld
    dim sFlds
    dim sRec
    dim sRecs
    dim sRecordSet
    dim lRecCnt

    sRecordSet = ""
    sRecs = ""
    lRecCnt = 0
    if rs.EOF or rs.BOF then
        RStoJSON = "null"
    else
        do while not rs.EOF and not rs.BOF
            lRecCnt = lRecCnt + 1
            sFlds = ""
            for each fld in rs.Fields
                sFld = """" & fld.Name & """:""" & toUnicode(fld.Value&"") & """"
                sFlds = sFlds & iif(sFlds <> "", ",", "") & sFld
            next 'fld
            sRec = "{" & sFlds & "}"
            sRecs = sRecs & iif(sRecs <> "", "," & vbCrLf, "") & sRec
            rs.MoveNext
        loop
        sRecordSet = "( {""Records"": [" & vbCrLf & sRecs & vbCrLf & "], "
        sRecordSet = sRecordSet & """RecordCount"":""" & lRecCnt & """ } )"
        RStoJSON = sRecordSet
    end if
end function

function toUnicode(str)
    dim x
    dim uStr
    dim uChr
    dim uChrCode
    uStr = ""
    for x = 1 to len(str)
        uChr = mid(str,x,1)
        uChrCode = asc(uChr)
        if uChrCode = 8 then ' backspace
            uChr = "\b"
        elseif uChrCode = 9 then ' tab
            uChr = "\t"
        elseif uChrCode = 10 then ' line feed
            uChr = "\n"
        elseif uChrCode = 12 then ' formfeed
            uChr = "\f"
        elseif uChrCode = 13 then ' carriage return
            uChr = "\r"
        elseif uChrCode = 34 then ' quote
            uChr = "\"""
        elseif uChrCode = 39 then ' apostrophe
            uChr = "\'"
        elseif uChrCode = 92 then ' backslash
            uChr = "\\"
        elseif uChrCode < 32 or uChrCode > 127 then ' non-ascii characters
            uChr = "\u" & right("0000" & CStr(uChrCode),4)
        end if
        uStr = uStr & uChr
    next
    toUnicode = uStr
end function

function iif(cond,tv,fv)
    if cond then
        iif = tv
    else
        iif = fv
    end if
end function

</code>

Thankyou for your assistance.

Normally, you would expect the JSON returned to dojo for a filtering select to be of the form:

{
identifier:"fOffice",
items: [
        {fOffice:"Dayton"},
        {fOffice:"Fairview Heights"}
       ]
}

taken from here:

http://dojotoolkit.org/book/dojo-book-0-9/part-2-dijit/form-validation-s...

The "identifier" field is important. "Items" is the expected field name for the object array to follow.

Modify your json prep code to write it back as above (and w/o the parens), and see if it works for you.

Later, it would be better to wrap your server response in comments, i.e.,

Response.Write "/*" + jsonStrObj + "*/"

and set your server's output contentType (within the code block that is writing the content to the client) to "json-comment-filtered".

Thank you frankf,

Your suggestions helped me get the code working. For the benefit of others here is the revised JSON data creator.

<code>
<%

'Function to convert an ADO recordset into a JSON object
'
'Written by Tracy Dryden, Commonwealth Technology Group, Inc.
'
'Released to the public domain.

function RStoJSON(rs)
dim sFld
dim sFlds
dim sRec
dim sRecs
dim sRecordSet
dim lRecCnt
dim identifierValue

sRecordSet = ""
sRecs = ""
lRecCnt = 0
if rs.EOF or rs.BOF then
RStoJSON = "null"
else
do while not rs.EOF and not rs.BOF
lRecCnt = lRecCnt + 1
sFlds = ""
for each fld in rs.Fields
'*** Modified by Gene Evans - Removed quotes from around field name. ***
'sFld = """" & fld.Name & """:""" & toUnicode(fld.Value&"") & """"
sFld = fld.Name & ":""" & toUnicode(fld.Value&"") & """"
sFlds = sFlds & iif(sFlds <> "", ",", "") & sFld
identifierValue = fld.Name
next 'fld
sRec = "{" & sFlds & "}"
sRecs = sRecs & iif(sRecs <> "", "," & vbCrLf, "") & sRec
rs.MoveNext
loop

'*** Modified by Gene Evans - Removed leading and trailing outside parens, added identifier, ***
'*** removed quotes from around attribute names, and changed Recordcount to itemCount. ***
'sRecordSet = "( {""Records"": [" & vbCrLf & sRecs & vbCrLf & "], "
'sRecordSet = sRecordSet & """RecordCount"":""" & lRecCnt & """ } )"
sRecordSet = "{ identifier: """ & identifierValue & ""","
sRecordSet = sRecordSet & vbCrLf & "items: [" & vbCrLf & sRecs & vbCrLf & "],"
sRecordSet = sRecordSet & vbCrLf & "itemCount: """ & lRecCnt & """ }"
RStoJSON = sRecordSet
end if
end function

function toUnicode(str)
dim x
dim uStr
dim uChr
dim uChrCode
uStr = ""
for x = 1 to len(str)
uChr = mid(str,x,1)
uChrCode = asc(uChr)
if uChrCode = 8 then ' backspace
uChr = "\b"
elseif uChrCode = 9 then ' tab
uChr = "\t"
elseif uChrCode = 10 then ' line feed
uChr = "\n"
elseif uChrCode = 12 then ' formfeed
uChr = "\f"
elseif uChrCode = 13 then ' carriage return
uChr = "\r"
elseif uChrCode = 34 then ' quote
uChr = "\"""
elseif uChrCode = 39 then ' apostrophe
uChr = "\'"
elseif uChrCode = 92 then ' backslash
uChr = "\\"
elseif uChrCode < 32 or uChrCode > 127 then ' non-ascii characters
uChr = "\u" & right("0000" & CStr(uChrCode),4)
end if
uStr = uStr & uChr
next
toUnicode = uStr
end function

function iif(cond,tv,fv)
if cond then
iif = tv
else
iif = fv
end if
end function

</code>